Setup.bat

@echo off
setlocal enabledelayedexpansion
chcp 65001

:: BuildSystemMode: 0 = MSVC, 1 = WASM, 2 = Harmony
:: BuildMode: 0 = compat, 1 = core, 2 = gles, 3 = webgl1, 4 = webgl2, 5 = android, 6 = harmony
set BuildSystemMode=0
set BuildMode=-1
set BuildGles2=0

:: Android build type (mode 5): Debug or Release, used for the Gradle task and build result paths
set AndroidBuildType=Debug
:: Android build type (mode 5): -Pabi for Gradle (ABI_FILTER) and -DOHOS_ARCH for Harmony
set AndroidAbi=arm64-v8a
:: Android build type (mode 5): SDL2 version used by Android
set Sdl2Version=release-2.24.0

set QuietMode=0
set SourceCodePatched=0
set CurrentDir=%cd%
set OpenSceneGraphRoot=%CurrentDir%\..\OpenSceneGraph

:: PowerShell is used to keep the original timestamps of patched files, so that
:: patching/unpatching never looks like a source change to CMake/Ninja. If it is
:: not available the timestamps are left untouched, which is the old behaviour.
set UsePowerShellForTime=0
where powershell >nul 2>&1
if !errorlevel!==0 set UsePowerShellForTime=1

set OptionalDir=%1
if "!OptionalDir!"=="DEFAULT" (set BuildMode=0& set QuietMode=1)
if "!OptionalDir!"=="CORE" (set BuildMode=1& set QuietMode=1)
if "!OptionalDir!"=="GLES2" (set BuildMode=2& set BuildGles2=1& set QuietMode=1)
if "!OptionalDir!"=="GLES3" (set BuildMode=2& set BuildGles2=0& set QuietMode=1)
if "!OptionalDir!"=="WEBGL1" (set BuildMode=3& set QuietMode=1)
if "!OptionalDir!"=="WEBGL2" (set BuildMode=4& set QuietMode=1)
if "!OptionalDir!"=="ANDROID" (set BuildMode=5& set QuietMode=1)
if not "!BuildMode!"=="" set OptionalDir=%2

if not "!OptionalDir!"=="" (
    set "OptionalDir=!OptionalDir:\=/!"
    set "LastCharOfOptionalDir=!OptionalDir:~-1!"
    if "!LastCharOfOptionalDir!"=="/" (set "OptionalDir=!OptionalDir:~0,-1!")
)
set GLES_LibPath="!OptionalDir!/libGLESv2.lib"
set EGL_LibPath="!OptionalDir!/libEGL.lib"

where cmake --version >nul 2>&1
if not %errorlevel%==0 (
    echo CMake not found. Please make sure it can be found in PATH variable.
    goto exit
)

if not exist %OpenSceneGraphRoot%\ (
    git clone https://gitee.com/mirrors/OpenSceneGraph.git --depth 1 --branch OpenSceneGraph-3.6.5 %OpenSceneGraphRoot%\
    if not exist %OpenSceneGraphRoot%\ (
        echo OSG source folder not found. Please download and unzip it in ..\OpenSceneGraph.
        goto exit
    )
)

if "!QuietMode!"=="1" (goto postsel)
echo How do you like to compile OSG and osgVerse?
echo -----------------------------------
echo Please Select:
echo 0. Desktop / OpenGL Compatible Mode
echo 1. Desktop / OpenGL Core Mode
echo 2. Desktop / OpenGL ES
echo 3. WASM / WebGL 1.0
echo 4. WASM / WebGL 2.0 (optional with osgEarth)
echo 5. Android / OpenGLES 3
echo 6. Harmony / OpenGLES 3
echo q. Quit
echo -----------------------------------
set /p BuildMode="Enter selection [0-6] > "

:postsel
if "!BuildMode!"=="0" (
    set BuildResultChecker=build\sdk\lib\osgViewer.lib
    set CMakeResultChecker=build\osg_def\CMakeCache.txt
    goto precheck
)
if "!BuildMode!"=="1" (
    set BuildResultChecker=build\sdk_core\lib\osgViewer.lib
    set CMakeResultChecker=build\osg_core\CMakeCache.txt
    goto precheck
)
if "!BuildMode!"=="2" (
    set BuildResultChecker=build\sdk_es\lib\osgViewer.lib
    set CMakeResultChecker=build\osg_es\CMakeCache.txt

    if not exist %GLES_LibPath% (
        echo "libGLESv2.lib not found. Please run as follows: ./Setup.sh <path_of_libGLES>"
        goto exit
    )
    if not exist %EGL_LibPath% (
        echo "libEGL.lib not found. Please run as follows: ./Setup.sh <path_of_libEGL>"
        goto exit
    )
    goto precheck
)
if "!BuildMode!"=="3" (
    set BuildResultChecker=build\sdk_wasm\lib\libosgViewer.a
    set CMakeResultChecker=build\osg_wasm\CMakeCache.txt
    set BuildSystemMode=1
    goto precheck
)
if "!BuildMode!"=="4" (
    set BuildResultChecker=build\sdk_wasm2\lib\libosgViewer.a
    set CMakeResultChecker=build\osg_wasm2\CMakeCache.txt
    set BuildSystemMode=1
    goto precheck
)
if "!BuildMode!"=="5" (
    goto precheck_android
)
if "!BuildMode!"=="6" (
    set BuildResultChecker=build\sdk_harmony\lib\libosgViewer.so
    set CMakeResultChecker=build\osg_harmony\CMakeCache.txt
    set BuildSystemMode=2
    goto precheck
)
if "!BuildMode!"=="q" (
    goto exit
)
echo Invalid option selected.
goto exit

:: Check if CMake is already configured, or OSG is already built
:precheck
set SkipOsgBuild=0
set UseWasmOption=1
if exist %CurrentDir%\%BuildResultChecker% (
    set SkipOsgBuild=1
    if "!QuietMode!"=="0" (
        set /p RebuildFlag="Would you like to use current OSG built (default: yes)? (y/n) > "
        if /i "!RebuildFlag!"=="n" set SkipOsgBuild=0
    )
)

set BasicCmakeOptions=""
set BuildTypeString=Release
ver > nul
if "!BuildSystemMode!"=="0" (
    where msbuild -version >nul 2>&1
    if not %errorlevel%==0 (
        echo %errorlevel% MsBuild not found. Please start from Developer Command Prompt of Visual Studio.
        goto exit
    )

    :: Get Visual Studio version
    for /f "tokens=1 delims=." %%a in ('msbuild -nologo -version 2^>^&1') do (
        set "MSBUILD_MAJOR=%%a"
        echo Found Visual Studio version: %%a
        goto found_msbuild
    )

:found_msbuild
    if "%MSBUILD_MAJOR%"=="18" (
        set "CMAKE_GENERATOR=Visual Studio 18 2026"
    ) else if "%MSBUILD_MAJOR%"=="17" (
        set "CMAKE_GENERATOR=Visual Studio 17 2022"
    ) else if "%MSBUILD_MAJOR%"=="16" (
        set "CMAKE_GENERATOR=Visual Studio 16 2019"
    ) else if "%MSBUILD_MAJOR%"=="15" (
        set "CMAKE_GENERATOR=Visual Studio 15 2017"
    ) else if "%MSBUILD_MAJOR%"=="14" (
        set "CMAKE_GENERATOR=Visual Studio 14 2015"
    ) else (
        echo Unsupported Visual Studio version: %MSBUILD_MAJOR%
        goto exit
    )

    :: Desktop build
    if "!QuietMode!"=="0" (
        set /p DebugLibFlag="Would you like to build Debug libraries (default: Release)? (y/n) > "
        if /i "!DebugLibFlag!"=="y" set BuildTypeString=Debug
    )
    
    set ThirdPartyBuildDir=%CurrentDir%\build\3rdparty
    set BasicCmakeOptions=-G"%CMAKE_GENERATOR%" -A x64 -DCMAKE_CONFIGURATION_TYPES=!BuildTypeString!
    echo Using CMake generator: %CMAKE_GENERATOR%
    if "!BuildMode!"=="2" (
        :: OpenGL ES
        if not "!SkipOsgBuild!"=="1" (
            set /p Gles2Flag="Would you like to compile GLES2 version (default: GLES3)? (y/n) > "
            if /i "!Gles2Flag!"=="y" set BuildGles2=1
        )
    )
)
if "!BuildSystemMode!"=="1" (
    where ninja --version >nul 2>&1
    if not %errorlevel%==0 (
        echo Ninja not found. Please make sure it can be found in PATH variable.
        goto exit
    )

    :: WASM (WebGL 1 and WebGL 2)
    if not defined EMSDK (
        echo EMSDK variable not found. Please download Emscripten and run 'emsdk_env.bat' before current work.
        goto exit
    )
    if not exist %EMSDK%\ (
        echo EMSDK folder not found. Please download Emscripten and run 'emsdk_env.bat' before current work.
        goto exit
    )

    if "!QuietMode!"=="0" (
        set /p Wasm64Flag="Would you like to use WASM 64bit (experimental, default: no)? (y/n) > "
        if /i "!Wasm64Flag!"=="y" set UseWasmOption=2
    )
    set EmsdkToolchain="%EMSDK%\upstream\emscripten\cmake\Modules\Platform\Emscripten.cmake"
    set ThirdPartyBuildDir=%CurrentDir%\build\3rdparty_wasm
    set BasicCmakeOptions=-GNinja -DCMAKE_BUILD_TYPE=Release
)
if "!BuildSystemMode!"=="2" (
    if not defined HARMONY_CMD (
        echo HARMONY_CMD variable not found. Please download HarmonyCmd-26.x.x.zip and extract it to specified folder.
        goto exit
    )
    if not exist %HARMONY_CMD%\ (
        echo HarmonyCmd folder not found. Please extract HarmonyCmd to folder and set variable HARMONY_CMD.
        goto exit
    )

    :: Default architecture is arm64-v8a (aarch64). Alternatives: armeabi-v7a (arm-linux-ohos), x86_64 (x86_64-linux-ohos)
    set HarmonyToolchain="%HARMONY_CMD%\sdk\default\openharmony\native\build\cmake\ohos.toolchain.cmake"
    set "PATH=%HARMONY_CMD%\sdk\default\openharmony\native\build-tools\cmake\bin;%PATH%"
    set ThirdPartyBuildDir=%CurrentDir%\build\3rdparty_harmony
    set BasicCmakeOptions=-GNinja -DCMAKE_BUILD_TYPE=Release -DOHOS_ARCH=%AndroidAbi%

    set HarmonyLibDir="%HARMONY_CMD%/sdk/default/openharmony/native/sysroot/usr/lib/aarch64-linux-ohos"
    set "HarmonyLibDir=!HarmonyLibDir:\=/!"
    set GLES_LibPath="!HarmonyLibDir!/libGLESv3.so"
    set EGL_LibPath="!HarmonyLibDir!/libEGL.so"
)

:: Compile 3rdparties
echo *** Building 3rdparty libraries...
if not exist %ThirdPartyBuildDir%\ mkdir %ThirdPartyBuildDir%
set ExtraOptions=""
set ExtraOptions2=""
if "!BuildSystemMode!"=="0" (
    if not "!SkipOsgBuild!"=="1" (
        cd %ThirdPartyBuildDir%
        cmake %BasicCmakeOptions% "%CurrentDir%\helpers\toolchain_builder"
        cmake --build . -j8 --config !BuildTypeString!
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildSystemMode!"=="1" (
    if not "!SkipOsgBuild!"=="1" (
        cd %ThirdPartyBuildDir%
        cmake %BasicCmakeOptions% -DCMAKE_TOOLCHAIN_FILE="%EmsdkToolchain%" -DUSE_WASM_OPTIONS=!UseWasmOption! "%CurrentDir%\helpers\toolchain_builder"
        cmake --build . -j8
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildSystemMode!"=="2" (
    if not "!SkipOsgBuild!"=="1" (
        cd %ThirdPartyBuildDir%
        cmake %BasicCmakeOptions% -DCMAKE_TOOLCHAIN_FILE="%HarmonyToolchain%" "%CurrentDir%\helpers\toolchain_builder"
        cmake --build . -j8
        if not !errorlevel! == 0 (goto exit)
    )
)

set ThirdDepOptions=%BasicCmakeOptions% -DVERSE_BUILD_3RDPARTIES=OFF -DCMAKE_POLICY_VERSION_MINIMUM=3.5
set ThirdDepIncludes=-DFREETYPE_INCLUDE_DIR_freetype2=%CurrentDir%\helpers\toolchain_builder\freetype\include ^
                     -DFREETYPE_INCLUDE_DIR_ft2build=%CurrentDir%\helpers\toolchain_builder\freetype\include ^
                     -DJPEG_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\jpeg ^
                     -DPNG_PNG_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\png ^
                     -DZLIB_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\zlib
if "!BuildSystemMode!"=="0" (
    set ThirdDepOptions=!ThirdDepOptions! !ThirdDepIncludes! ^
        -DFREETYPE_LIBRARY_RELEASE=%ThirdPartyBuildDir%\freetype\!BuildTypeString!\freetype.lib ^
        -DJPEG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\jpeg\!BuildTypeString!\jpeg.lib ^
        -DPNG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\png\!BuildTypeString!\png.lib ^
        -DZLIB_LIBRARY_RELEASE=%ThirdPartyBuildDir%\zlib\!BuildTypeString!\zlib.lib ^
        -DTIFF_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\tiff;%ThirdPartyBuildDir%\tiff ^
        -DTIFF_LIBRARY_RELEASE=%ThirdPartyBuildDir%\tiff\!BuildTypeString!\tiff.lib
)
if "!BuildSystemMode!"=="1" (
    set ThirdDepOptions=!ThirdDepOptions! !ThirdDepIncludes! ^
        -DFREETYPE_LIBRARY_RELEASE=%ThirdPartyBuildDir%\freetype\libfreetype.a ^
        -DJPEG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\jpeg\libjpeg.a ^
        -DPNG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\png\libpng.a ^
        -DZLIB_LIBRARY_RELEASE=%ThirdPartyBuildDir%\zlib\libzlib.a
    if exist "%CurrentDir%\..\Dependencies\wasm\lib\libtiff.a" (
        set ThirdDepOptions=!ThirdDepOptions! ^
            -DTIFF_INCLUDE_DIR=%CurrentDir%\..\Dependencies\wasm\include ^
            -DTIFF_LIBRARY_RELEASE=%CurrentDir%\..\Dependencies\wasm\lib\libtiff.a
    )
)
if "!BuildSystemMode!"=="2" (
    set ThirdDepOptions=!ThirdDepOptions! !ThirdDepIncludes! ^
        -DFREETYPE_LIBRARY_RELEASE=%ThirdPartyBuildDir%\freetype\libfreetype.a ^
        -DJPEG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\jpeg\libjpeg.a ^
        -DPNG_LIBRARY_RELEASE=%ThirdPartyBuildDir%\png\libpng.a ^
        -DZLIB_LIBRARY_RELEASE=%ThirdPartyBuildDir%\zlib\libzlib.a ^
        -DTIFF_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\tiff;%ThirdPartyBuildDir%\tiff ^
        -DTIFF_LIBRARY_RELEASE=%ThirdPartyBuildDir%\tiff\libtiff.a
    )
)

:: Fix some OpenSceneGraph compile errors
set SedEXE=%CurrentDir%\wasm\sed.exe
if not "!SkipOsgBuild!"=="1" (
    echo *** Automatically patching source code...
    set SourceCodePatched=1

    if exist "%OpenSceneGraphRoot%\src\osgUtil\tristripper\include\detail\graph_array.h" (
        %SedEXE% -i.bak "s/std::mem_fun_ref/std::mem_fn/g" "%OpenSceneGraphRoot%\src\osgUtil\tristripper\include\detail\graph_array.h"
    )
    %SedEXE% -i.bak "s/if defined(__ANDROID__)/if defined(__EMSCRIPTEN__) || defined(__ANDROID__)/g" "%OpenSceneGraphRoot%\src\osgDB\FileUtils.cpp"
    %SedEXE% -i.bak "s/TARGET_EXTERNAL_LIBRARIES ${FREETYPE_LIBRARIES}/TARGET_EXTERNAL_LIBRARIES ${PNG_LIBRARY} ${FREETYPE_LIBRARIES}/g" "%OpenSceneGraphRoot%\src\osgPlugins\freetype\CMakeLists.txt"
    %SedEXE% -i.bak "s/SET(TARGET_LIBRARIES_VARS TIFF_LIBRARY)/SET(TARGET_LIBRARIES_VARS TIFF_LIBRARY JPEG_LIBRARY)/g" "%OpenSceneGraphRoot%\src\osgPlugins\tiff\CMakeLists.txt"
    %SedEXE% -i.bak "s/_FPOSOFF/(long long)/g" "%OpenSceneGraphRoot%\src\osgPlugins\osga\OSGA_Archive.cpp"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(cfg)/#ADD_PLUGIN_DIRECTORY(#cfg)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(obj)/#ADD_PLUGIN_DIRECTORY(#obj)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(ffmpeg)/#ADD_PLUGIN_DIRECTORY(#ffmpeg)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/TIFF_FOUND AND OSG_CPP_EXCEPTIONS_AVAILABLE/TIFF_FOUND/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/IF(WIN32 AND NOT ANDROID)/IF(${OSG_WINDOWING_SYSTEM} STREQUAL \"Win32\" AND WIN32 AND NOT ANDROID)/g" "%OpenSceneGraphRoot%\src\osgViewer\CMakeLists.txt"
    %SedEXE% -i.bak "s/ANDROID_3RD_PARTY()/#ANDROID_3RD_PARTY(#)/g" "%OpenSceneGraphRoot%\CMakeLists.txt"

    :: Fix WebGL running errors
    if "!BuildMode!"=="3" (
        %SedEXE% -i.bak "s#dlopen(#NULL;\/\/dlopen\/\/(#g" "%OpenSceneGraphRoot%\src\osgDB\DynamicLibrary.cpp"
        %SedEXE% -i.bak "s#isTexture2DArraySupported = validContext#isTexture2DArraySupported = isTexture3DSupported;\/\/validContext#g" "%OpenSceneGraphRoot%\src\osg\GLExtensions.cpp"
    )
    if "!BuildMode!"=="4" (
        %SedEXE% -i.bak "s#dlopen(#NULL;\/\/dlopen\/\/(#g" "%OpenSceneGraphRoot%\src\osgDB\DynamicLibrary.cpp"
        %SedEXE% -i.bak "s#isTexture2DArraySupported = validContext#isTexture2DArraySupported = isTexture3DSupported;\/\/validContext#g" "%OpenSceneGraphRoot%\src\osg\GLExtensions.cpp"
    )
    %SedEXE% -i.bak "s#ifndef GL_EXT_texture_compression_s3tc#if defined(GL_EXT_texture_compression_s3tc)==0 || defined(GL_EXT_texture_compression_s3tc_srgb)==0#g" "%OpenSceneGraphRoot%\include/osg/Texture"
    %SedEXE% -i.bak "s#glTexParameterf(target, GL_TEXTURE_LOD_BIAS, _lodbias)#;\/\/glTexParameterf(target, \/\/GL_TEXTURE_LOD_BIAS, _lodbias)#g" "%OpenSceneGraphRoot%\src\osg\Texture.cpp"
    %SedEXE% -i.bak "s#std::max#osg::maximum#g" "%OpenSceneGraphRoot%\src\osg\Texture.cpp"
    %SedEXE% -i.bak "s#case(GL_HALF_FLOAT):#case GL_HALF_FLOAT: case 0x8D61:#g" "%OpenSceneGraphRoot%\src\osg\Image.cpp"

    :: Fix OpenHarmony compilation errors
    if "!BuildMode!"=="6" (
        %SedEXE% -i.bak "s/ADD_DEFINITIONS(-DHAVE_PTHREAD_TESTCANCEL)/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_TESTCANCEL)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
        %SedEXE% -i.bak "s/ADD_DEFINITIONS(-DHAVE_PTHREAD_CANCEL)/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_CANCEL)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
        %SedEXE% -i.bak "s/ADD_DEFINITIONS(-DHAVE_PTHREAD_SETCANCELSTATE)/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_SETCANCELSTATE)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
    )
    call :KeepOsgFileTimes
)

:: Compile OpenSceneGraph
echo *** Building OpenSceneGraph...
if "!BuildMode!"=="0" (
    :: OpenGL Compatible Profile
    if not exist %CurrentDir%\build\osg_def\ mkdir %CurrentDir%\build\osg_def
    set ExtraOptions=-DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_def
        cmake !ThirdDepOptions! !ExtraOptions! %OpenSceneGraphRoot%
        cmake --build . -j8 --target install --config !BuildTypeString!
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildMode!"=="1" (
    :: OpenGL Core Profile
    if not exist %CurrentDir%\build\osg_core\ mkdir %CurrentDir%\build\osg_core
    set ExtraOptions=-DOPENGL_PROFILE=GLCORE ^
        -DGLCORE_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl ^
        -DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl ^
        -DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk_core
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_core
        echo "cmake !ThirdDepOptions! !ExtraOptions! %OpenSceneGraphRoot%"
        cmake !ThirdDepOptions! !ExtraOptions! %OpenSceneGraphRoot%
        cmake --build . -j8 --target install --config !BuildTypeString!
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildMode!"=="2" (
    :: OpenGL ES
    if not exist %CurrentDir%\build\osg_es\ mkdir %CurrentDir%\build\osg_es
    set ExtraOptions=-DOSG_WINDOWING_SYSTEM=None ^
        -DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl ^
        -DEGL_LIBRARY=%EGL_LibPath% -DOPENGL_gl_LIBRARY=%GLES_LibPath% ^
        -DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk_es
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_es
        if "!BuildGles2!"=="1" (
            cmake !ThirdDepOptions! !ExtraOptions! -DOPENGL_PROFILE=GLES2 %OpenSceneGraphRoot%
        ) else (
            cmake !ThirdDepOptions! !ExtraOptions! -DOPENGL_PROFILE=GLES3 %OpenSceneGraphRoot%
        )
        cmake --build . -j8 --target install --config !BuildTypeString!
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildMode!"=="3" (
    :: WASM toolchain: WebGL 1
    if not exist %CurrentDir%\build\osg_wasm\ mkdir %CurrentDir%\build\osg_wasm
    set ExtraOptions=-DCMAKE_TOOLCHAIN_FILE="%EmsdkToolchain%" ^
        -DCMAKE_INCLUDE_PATH=%CurrentDir%\helpers\toolchain_builder\opengl ^
        -DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk_wasm ^
        -DUSE_WASM_OPTIONS=!UseWasmOption! ^
        -DOSG_SOURCE_DIR=%OpenSceneGraphRoot% ^
        -DOSG_BUILD_DIR=%CurrentDir%\build\osg_wasm\osg
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_wasm
        cmake !ThirdDepOptions! !ExtraOptions! %CurrentDir%\helpers\osg_builder\wasm
        cmake --build . -j8 --target install --config Release
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildMode!"=="4" (
    :: WASM toolchain: WebGL 2
    if not exist %CurrentDir%\build\osg_wasm2\ mkdir %CurrentDir%\build\osg_wasm2
    set ExtraOptions=-DCMAKE_TOOLCHAIN_FILE="%EmsdkToolchain%" ^
        -DCMAKE_INCLUDE_PATH=%CurrentDir%\helpers\toolchain_builder\opengl ^
        -DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk_wasm2 ^
        -DUSE_WASM_OPTIONS=!UseWasmOption! ^
        -DOSG_SOURCE_DIR=%OpenSceneGraphRoot% ^
        -DOSG_BUILD_DIR=%CurrentDir%\build\osg_wasm2\osg
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_wasm2
        cmake !ThirdDepOptions! !ExtraOptions! %CurrentDir%\helpers\osg_builder\wasm2
        cmake --build . -j8 --target install --config Release
        if not !errorlevel! == 0 (goto exit)
    )
)
if "!BuildMode!"=="6" (
    :: Harmony: OpenGLES 3
    if not exist %CurrentDir%\build\osg_harmony\ mkdir %CurrentDir%\build\osg_harmony
    set ExtraOptions=-DCMAKE_TOOLCHAIN_FILE="%HarmonyToolchain%" -DOSG_WINDOWING_SYSTEM=None ^
        -DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl;%CurrentDir%\helpers\osg_builder\ohos ^
        -DEGL_LIBRARY=%EGL_LibPath% -DOPENGL_gl_LIBRARY=%GLES_LibPath% ^
        -DCMAKE_INSTALL_PREFIX=%CurrentDir%\build\sdk_harmony ^
        -D_OPENTHREADS_ATOMIC_USE_GCC_BUILTINS_EXITCODE="0"
    if not "!SkipOsgBuild!"=="1" (
        cd %CurrentDir%\build\osg_harmony
        cmake !ThirdDepOptions! !ExtraOptions! -DOPENGL_PROFILE=GLES3 %OpenSceneGraphRoot%
        cmake --build . -j8 --target install
        if not !errorlevel! == 0 (goto exit)
    )
)

:: Build osgEarth (Optional)
set WithOsgEarth=0
if "!BuildMode!"=="4" (
    if exist %CurrentDir%\..\osgearth-wasm\ (
        echo *** Building osgEarth 2.10...
        if not exist %CurrentDir%\build\osgearth_wasm2\ mkdir %CurrentDir%\build\osgearth_wasm2
        set ExtraOptions2=-DOSG_DIR=%CurrentDir%\build\sdk_wasm2 ^
            -DTHIRDPARTY_ROOT=%CurrentDir%\..\Dependencies\wasm ^
            -DUSE_WASM_OPTIONS=!UseWasmOption! ^
            -DOSGEARTH_SOURCE_DIR=%CurrentDir%\..\osgearth-wasm ^
            -DOSGEARTH_BUILD_DIR=%CurrentDir%\build\osgearth_wasm2\osgearth
        cd %CurrentDir%\build\osgearth_wasm2
        cmake %BasicCmakeOptions% !ExtraOptions! !ExtraOptions2! %CurrentDir%\helpers\osg_builder\wasm2_oe
        cmake --build . -j8 --target install --config Release
        set WithOsgEarth=1
    ) else (
        echo osgEarth-WASM not found. Please download it and unzip in ..\osgearth-wasm if you wish.
    )
)

:: Build osgVerse
echo *** Building osgVerse...
set OsgRootLocation=""
if "!BuildMode!"=="0" (
    :: Desktop: OpenGL Compatible Profile
    if not exist %CurrentDir%\build\verse_def\ mkdir %CurrentDir%\build\verse_def
    cd %CurrentDir%\build\verse_def
    cmake !ThirdDepOptions! !ExtraOptions! -DOSG_ROOT="%CurrentDir%\build\sdk" %CurrentDir%
    cmake --build . -j8 --target install --config !BuildTypeString!
    if not !errorlevel! == 0 (goto exit)
)
if "!BuildMode!"=="1" (
    :: Desktop: OpenGL Core Profile
    if not exist %CurrentDir%\build\verse_core\ mkdir %CurrentDir%\build\verse_core
    cd %CurrentDir%\build\verse_core
    set ExtraOptions2=-DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl
    cmake !ThirdDepOptions! !ExtraOptions! !ExtraOptions2! -DOSG_ROOT="%CurrentDir%\build\sdk_core" %CurrentDir%
    cmake --build . -j8 --target install --config !BuildTypeString!
    if not !errorlevel! == 0 (goto exit)
)
if "!BuildMode!"=="2" (
    :: Desktop: OpenGL ES
    if not exist %CurrentDir%\build\verse_es\ mkdir %CurrentDir%\build\verse_es
    cd %CurrentDir%\build\verse_es
    set ExtraOptions2=-DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl ^
                      -DOSG_EGL_LIBRARY=%EGL_LibPath% -DOSG_GLES_LIBRARY=%GLES_LibPath%
    cmake !ThirdDepOptions! !ExtraOptions! !ExtraOptions2! -DOSG_ROOT="%CurrentDir%\build\sdk_es" %CurrentDir%
    cmake --build . -j8 --target install --config !BuildTypeString!
    if not !errorlevel! == 0 (goto exit)
)
if "!BuildMode!"=="3" (
    :: WASM toolchain: WebGL 1
    if not exist %CurrentDir%\build\verse_wasm\ mkdir %CurrentDir%\build\verse_wasm
    set OsgRootLocation=%CurrentDir%\build\sdk_wasm
    cd %CurrentDir%\build\verse_wasm
    cmake !ThirdDepOptions! !ExtraOptions! -DUSE_WASM_OPTIONS=!UseWasmOption! -DOSG_ROOT="!OsgRootLocation!" %CurrentDir%
    cmake --build . -j8 --target install --config Release
    if not !errorlevel! == 0 (goto exit)
)
if "!BuildMode!"=="4" (
    :: WASM toolchain: WebGL 2
    if not exist %CurrentDir%\build\verse_wasm2\ mkdir %CurrentDir%\build\verse_wasm2
    set OsgRootLocation=%CurrentDir%\build\sdk_wasm2
    cd %CurrentDir%\build\verse_wasm2
    cmake !ThirdDepOptions! !ExtraOptions! -DUSE_WASM_OPTIONS=!UseWasmOption! -DUSE_WASM_OSGEARTH=!WithOsgEarth! -DOSG_ROOT="!OsgRootLocation!" %CurrentDir%
    cmake --build . -j8 --target install --config Release
    if not !errorlevel! == 0 (goto exit)
)
if "!BuildMode!"=="6" (
    :: Harmony toolchain: OpenGL ES
    if not exist %CurrentDir%\build\verse_harmony\ mkdir %CurrentDir%\build\verse_harmony
    cd %CurrentDir%\build\verse_harmony
    set ExtraOptions2=-DOPENGL_INCLUDE_DIR=%CurrentDir%\helpers\toolchain_builder\opengl ^
                      -DOSG_EGL_LIBRARY=%EGL_LibPath% -DOSG_GLES_LIBRARY=%GLES_LibPath% -DVERSE_ENABLE_GLFW=OFF
    cmake !ThirdDepOptions! !ExtraOptions! !ExtraOptions2! -DOSG_ROOT="%CurrentDir%\build\sdk_harmony" %CurrentDir%
    cmake --build . -j8 --target install
    if not !errorlevel! == 0 (goto exit)
)
goto exit

:: Android / gradle
:precheck_android
set SedEXE=%CurrentDir%\wasm\sed.exe
set Sdl2Root=%CurrentDir%\..\SDL2
set GradleLocalPropFile=%CurrentDir%\android\local.properties
set GradleSettingsFile=%CurrentDir%\android\settings.gradle

where gradle -v >nul 2>&1
if not %errorlevel%==0 (
    echo Gradle failed. Please make sure it can be found in PATH variable and JAVA_HOME points to JDK 11 or 17.
    goto exit
)

if not exist %Sdl2Root%\ (
    echo SDL2 source folder not found. Cloning %Sdl2Version% in ..\SDL2...
    git clone --depth 1 --branch %Sdl2Version% https://github.com/libsdl-org/SDL.git %Sdl2Root%\
    if not exist %Sdl2Root%\ (
        echo SDL2 source folder not found. Please download and unzip it in ..\SDL2.
        goto exit
    )
)

:: Migrate the deprecated ndk.dir entry to ndk.path (read by gradle.ext.ndkPath)
if exist "%GradleLocalPropFile%" (
    findstr /b /c:"ndk.dir=" "%GradleLocalPropFile%" >nul 2>&1
    if !errorlevel!==0 (
        %SedEXE% -i.bak "s/^ndk\.dir=/ndk.path=/" "%GradleLocalPropFile%"
        echo Replaced deprecated ndk.dir with ndk.path in local.properties...
    )
)

if not exist %GradleLocalPropFile% (
    if defined ANDROID_SDK (
        if defined ANDROID_NDK (
            set "AndroidPathSDK0=!ANDROID_SDK!"
            set "AndroidPathNDK0=!ANDROID_NDK!"
            set "AndroidPathSDK=!AndroidPathSDK0:\=/!"
            set "AndroidPathNDK=!AndroidPathNDK0:\=/!"
            @echo off
            (
                echo sdk.dir=!AndroidPathSDK!
                echo ndk.path=!AndroidPathNDK!
            ) > "%GradleLocalPropFile%"
        ) else (
            echo Environment variable ANDROID_NDK not set. Unable to create local.properties.
            goto exit
        )
    ) else (
        echo Environment variable ANDROID_SDK not set. Unable to create local.properties.
        goto exit
    )
)

if "!QuietMode!"=="0" (
    set /p AndroidCheckingFlag="Would you like to set a specific SDK version (default: no)? (y/n) > "
    if /i "!AndroidCheckingFlag!"=="y" (
        set /p BuildToolsVersion="Please set build-tools version (e.g. 32.0.0) > "
        set /p TargetSdkVersion="Please set target SDK version (e.g. 32) > "
        set /p MinimumSdkVersion="Please set minimum SDK version (e.g. 21) > "
        @echo off
        (
            echo gradle.ext.buildToolsVersion = '!BuildToolsVersion!'
            echo gradle.ext.sdkVersion = !TargetSdkVersion!
            echo gradle.ext.minSdkVersion = !MinimumSdkVersion!
            echo gradle.ext.targetSdkVersion = !TargetSdkVersion!
            echo gradle.ext.libDistributionRoot = '../build'
            echo include ':thirdparty'
            echo include ':sdl2'
            echo include ':osg'
            echo include ':osgverse'
            echo include ':app'
        ) > "%GradleSettingsFile%"
    )
) else (
    :: TODO: auto check and create %GradleSettingsFile%?
    echo "Ignore creation of %GradleSettingsFile%..."
)

cd %CurrentDir%\android
gradle assemble%AndroidBuildType% -Pabi=%AndroidAbi%
:: adb install -r android\app\build\outputs\apk\debug\app-debug.apk
:: adb logcat -s osgVerse SDL

:exit
if not %errorlevel%==0 (
    echo Last error = %errorlevel%
    pause
)
cd %CurrentDir%

:: Reset some OpenSceneGraph source code
if "!SourceCodePatched!"=="1" (
    echo *** Automatically unpatching source code...
    %SedEXE% -i.bak "s/TARGET_EXTERNAL_LIBRARIES ${PNG_LIBRARY} ${FREETYPE_LIBRARIES}/TARGET_EXTERNAL_LIBRARIES ${FREETYPE_LIBRARIES}/g" "%OpenSceneGraphRoot%\src\osgPlugins\freetype\CMakeLists.txt"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(#cfg)/#ADD_PLUGIN_DIRECTORY(cfg)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(#obj)/#ADD_PLUGIN_DIRECTORY(obj)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/ADD_PLUGIN_DIRECTORY(#ffmpeg)/#ADD_PLUGIN_DIRECTORY(ffmpeg)/g" "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
    %SedEXE% -i.bak "s/IF(${OSG_WINDOWING_SYSTEM} STREQUAL \"Win32\" AND WIN32 AND NOT ANDROID)/IF(WIN32 AND NOT ANDROID)/g" "%OpenSceneGraphRoot%\src\osgViewer\CMakeLists.txt"
    %SedEXE% -i.bak "s/#ANDROID_3RD_PARTY(#)/ANDROID_3RD_PARTY()/g" "%OpenSceneGraphRoot%\CMakeLists.txt"
    %SedEXE% -i.bak "s#NULL;\/\/dlopen\/\/(#dlopen(#g" "%OpenSceneGraphRoot%\src\osgDB\DynamicLibrary.cpp"
    %SedEXE% -i.bak "s#;\/\/glTexParameterf(target, \/\/GL_TEXTURE_LOD_BIAS, _lodbias)#glTexParameterf(target, GL_TEXTURE_LOD_BIAS, _lodbias)#g" "%OpenSceneGraphRoot%\src\osg\Texture.cpp"
    %SedEXE% -i.bak "s#osg::maximum#std::max#g" "%OpenSceneGraphRoot%\src\osg\Texture.cpp"
    %SedEXE% -i.bak "s#isTexture2DArraySupported = isTexture3DSupported;\/\/validContext#isTexture2DArraySupported = validContext#g" "%OpenSceneGraphRoot%\src\osg\GLExtensions.cpp"

    if "!BuildMode!"=="6" (
        %SedEXE% -i.bak "s/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_TESTCANCEL)/ADD_DEFINITIONS(-DHAVE_PTHREAD_TESTCANCEL)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
        %SedEXE% -i.bak "s/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_CANCEL)/ADD_DEFINITIONS(-DHAVE_PTHREAD_CANCEL)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
        %SedEXE% -i.bak "s/#ADD_DEFINITIONS(#-DHAVE_PTHREAD_SETCANCELSTATE)/ADD_DEFINITIONS(-DHAVE_PTHREAD_SETCANCELSTATE)/g" "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
    )
    call :KeepOsgFileTimes
)
echo Quited.
endlocal
goto :eof

:: Keep the original timestamp of a file after it has been rewritten by sed, using
:: the ".bak" copy created by sed. A file that is not patched (or kept) is ignored.
:KeepFileTime
set KeepTimeFile=%~1
set KeepTimeBak=%~1.bak
if not exist "!KeepTimeFile!" exit /b 0
if not exist "!KeepTimeBak!" exit /b 0
if not "!UsePowerShellForTime!"=="1" exit /b 0
powershell -NoProfile -Command "(Get-Item -LiteralPath '!KeepTimeFile!').LastWriteTime=(Get-Item -LiteralPath '!KeepTimeBak!').LastWriteTime" >nul 2>&1
exit /b 0

:: Get back the timestamps of every OpenSceneGraph file that may have been patched
:KeepOsgFileTimes
if not "!UsePowerShellForTime!"=="1" exit /b 0
call :KeepFileTime "%OpenSceneGraphRoot%\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgPlugins\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgPlugins\freetype\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgPlugins\tiff\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgPlugins\osga\OSGA_Archive.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgViewer\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\OpenThreads\pthreads\CMakeLists.txt"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgDB\FileUtils.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgDB\DynamicLibrary.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osgUtil\tristripper\include\detail\graph_array.h"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osg\Texture.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osg\Image.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\src\osg\GLExtensions.cpp"
call :KeepFileTime "%OpenSceneGraphRoot%\include\osg\Texture"
exit /b 0