|
| 1 | +/* |
| 2 | + * Copyright (c) Meta Platforms, Inc. and affiliates. |
| 3 | + * |
| 4 | + * This source code is licensed under the MIT license found in the |
| 5 | + * LICENSE file in the root directory of this source tree. |
| 6 | + */ |
| 7 | + |
| 8 | +#import "RNTesterTabsIOSComponentView.h" |
| 9 | + |
| 10 | +#import <React/RCTConversions.h> |
| 11 | +#import <React/UIView+React.h> |
| 12 | +#import <react/renderer/components/AppSpecs/ComponentDescriptors.h> |
| 13 | +#import <react/renderer/components/AppSpecs/EventEmitters.h> |
| 14 | +#import <react/renderer/components/AppSpecs/Props.h> |
| 15 | + |
| 16 | +#include <algorithm> |
| 17 | + |
| 18 | +using namespace facebook::react; |
| 19 | + |
| 20 | +/** |
| 21 | + * A tab's view controller, which reports when the tab bar or window changes |
| 22 | + * the area its content needs to clear. |
| 23 | + */ |
| 24 | +@interface RNTesterTabViewController : UIViewController |
| 25 | +@property (nonatomic, copy) void (^safeAreaInsetsDidChange)(UIEdgeInsets insets); |
| 26 | +@end |
| 27 | + |
| 28 | +@implementation RNTesterTabViewController |
| 29 | + |
| 30 | +- (void)viewSafeAreaInsetsDidChange |
| 31 | +{ |
| 32 | + [super viewSafeAreaInsetsDidChange]; |
| 33 | + if (self.safeAreaInsetsDidChange != nil) { |
| 34 | + self.safeAreaInsetsDidChange(self.view.safeAreaInsets); |
| 35 | + } |
| 36 | +} |
| 37 | + |
| 38 | +@end |
| 39 | + |
| 40 | +@interface RNTesterTabsIOSComponentView () <UITabBarControllerDelegate> |
| 41 | +@end |
| 42 | + |
| 43 | +@implementation RNTesterTabsIOSComponentView { |
| 44 | + UITabBarController *_tabBarController; |
| 45 | + // Holds the mounted React children, and moves into the selected tab. |
| 46 | + UIView *_containerView; |
| 47 | + std::vector<std::string> _tabKeys; |
| 48 | + UIEdgeInsets _contentInsets; |
| 49 | +} |
| 50 | + |
| 51 | ++ (ComponentDescriptorProvider)componentDescriptorProvider |
| 52 | +{ |
| 53 | + return concreteComponentDescriptorProvider<RNTesterTabsIOSComponentDescriptor>(); |
| 54 | +} |
| 55 | + |
| 56 | +// The view owns a view controller, which is not worth resetting for reuse. |
| 57 | ++ (BOOL)shouldBeRecycled |
| 58 | +{ |
| 59 | + return NO; |
| 60 | +} |
| 61 | + |
| 62 | +- (instancetype)initWithFrame:(CGRect)frame |
| 63 | +{ |
| 64 | + if (self = [super initWithFrame:frame]) { |
| 65 | + static const auto defaultProps = std::make_shared<const RNTesterTabsIOSProps>(); |
| 66 | + _props = defaultProps; |
| 67 | + |
| 68 | + _containerView = [UIView new]; |
| 69 | + _containerView.autoresizingMask = UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight; |
| 70 | + |
| 71 | + _tabBarController = [UITabBarController new]; |
| 72 | + _tabBarController.delegate = self; |
| 73 | + self.contentView = _tabBarController.view; |
| 74 | + } |
| 75 | + return self; |
| 76 | +} |
| 77 | + |
| 78 | +- (void)didMoveToWindow |
| 79 | +{ |
| 80 | + [super didMoveToWindow]; |
| 81 | + if (self.window == nil) { |
| 82 | + [_tabBarController willMoveToParentViewController:nil]; |
| 83 | + [_tabBarController removeFromParentViewController]; |
| 84 | + return; |
| 85 | + } |
| 86 | + |
| 87 | + UIViewController *parentViewController = self.reactViewController; |
| 88 | + if (parentViewController != nil && _tabBarController.parentViewController == nil) { |
| 89 | + [parentViewController addChildViewController:_tabBarController]; |
| 90 | + [_tabBarController didMoveToParentViewController:parentViewController]; |
| 91 | + } |
| 92 | +} |
| 93 | + |
| 94 | +#pragma mark - Children |
| 95 | + |
| 96 | +// Children are laid out against this view's bounds, which the tab's view shares, so they keep their |
| 97 | +// frames wherever the container moves. |
| 98 | +- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index |
| 99 | +{ |
| 100 | + [_containerView insertSubview:childComponentView atIndex:index]; |
| 101 | +} |
| 102 | + |
| 103 | +- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index |
| 104 | +{ |
| 105 | + [childComponentView removeFromSuperview]; |
| 106 | +} |
| 107 | + |
| 108 | +#pragma mark - Props |
| 109 | + |
| 110 | +- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps |
| 111 | +{ |
| 112 | + const auto &oldTabsProps = static_cast<const RNTesterTabsIOSProps &>(*_props); |
| 113 | + const auto &newTabsProps = static_cast<const RNTesterTabsIOSProps &>(*props); |
| 114 | + |
| 115 | + // RNTester's tabs are a constant, so they are built once, from the first props. |
| 116 | + bool tabsCreated = _tabKeys.empty(); |
| 117 | + if (tabsCreated) { |
| 118 | + [self createTabs:newTabsProps.tabs]; |
| 119 | + } |
| 120 | + if (tabsCreated || oldTabsProps.selectedTab != newTabsProps.selectedTab) { |
| 121 | + [self selectTab:newTabsProps.selectedTab]; |
| 122 | + } |
| 123 | + if (oldTabsProps.tabBarHidden != newTabsProps.tabBarHidden) { |
| 124 | + if (@available(iOS 18.0, tvOS 18.0, *)) { |
| 125 | + [_tabBarController setTabBarHidden:newTabsProps.tabBarHidden animated:NO]; |
| 126 | + } else { |
| 127 | + _tabBarController.tabBar.hidden = newTabsProps.tabBarHidden; |
| 128 | + } |
| 129 | + } |
| 130 | + |
| 131 | + [super updateProps:props oldProps:oldProps]; |
| 132 | +} |
| 133 | + |
| 134 | +- (void)createTabs:(const std::vector<RNTesterTabsIOSTabsStruct> &)tabs |
| 135 | +{ |
| 136 | + __weak RNTesterTabsIOSComponentView *weakSelf = self; |
| 137 | + NSMutableArray<UIViewController *> *viewControllers = [NSMutableArray arrayWithCapacity:tabs.size()]; |
| 138 | + _tabKeys.clear(); |
| 139 | + |
| 140 | + for (const auto &tab : tabs) { |
| 141 | + auto *viewController = [RNTesterTabViewController new]; |
| 142 | + viewController.tabBarItem = |
| 143 | + [[UITabBarItem alloc] initWithTitle:RCTNSStringFromString(tab.title) |
| 144 | + image:[UIImage systemImageNamed:RCTNSStringFromString(tab.systemImage)] |
| 145 | + tag:0]; |
| 146 | + viewController.tabBarItem.accessibilityIdentifier = RCTNSStringFromString(tab.testID); |
| 147 | + viewController.safeAreaInsetsDidChange = ^(UIEdgeInsets insets) { |
| 148 | + [weakSelf tabSafeAreaInsetsDidChange:insets]; |
| 149 | + }; |
| 150 | + [viewControllers addObject:viewController]; |
| 151 | + _tabKeys.push_back(tab.key); |
| 152 | + } |
| 153 | + |
| 154 | + _tabBarController.viewControllers = viewControllers; |
| 155 | +} |
| 156 | + |
| 157 | +- (void)selectTab:(const std::string &)key |
| 158 | +{ |
| 159 | + auto it = std::find(_tabKeys.begin(), _tabKeys.end(), key); |
| 160 | + if (it == _tabKeys.end()) { |
| 161 | + return; |
| 162 | + } |
| 163 | + _tabBarController.selectedIndex = std::distance(_tabKeys.begin(), it); |
| 164 | + |
| 165 | + UIView *tabView = _tabBarController.selectedViewController.view; |
| 166 | + _containerView.frame = tabView.bounds; |
| 167 | + [tabView addSubview:_containerView]; |
| 168 | +} |
| 169 | + |
| 170 | +#pragma mark - UITabBarControllerDelegate |
| 171 | + |
| 172 | +- (BOOL)tabBarController:(UITabBarController *)tabBarController |
| 173 | + shouldSelectViewController:(UIViewController *)viewController |
| 174 | +{ |
| 175 | + NSUInteger index = [tabBarController.viewControllers indexOfObject:viewController]; |
| 176 | + if (index != NSNotFound && _eventEmitter != nullptr) { |
| 177 | + static_cast<const RNTesterTabsIOSEventEmitter &>(*_eventEmitter).onTabPress({.key = _tabKeys[index]}); |
| 178 | + } |
| 179 | + // JS selects the tab by updating `selectedTab`. |
| 180 | + return NO; |
| 181 | +} |
| 182 | + |
| 183 | +#pragma mark - Insets |
| 184 | + |
| 185 | +- (void)updateEventEmitter:(const EventEmitter::Shared &)eventEmitter |
| 186 | +{ |
| 187 | + [super updateEventEmitter:eventEmitter]; |
| 188 | + // The insets can settle before the first event emitter arrives. |
| 189 | + UIViewController *selectedViewController = _tabBarController.selectedViewController; |
| 190 | + if (selectedViewController.isViewLoaded && selectedViewController.view.window != nil) { |
| 191 | + _contentInsets = UIEdgeInsetsZero; |
| 192 | + [self tabSafeAreaInsetsDidChange:selectedViewController.view.safeAreaInsets]; |
| 193 | + } |
| 194 | +} |
| 195 | + |
| 196 | +- (void)tabSafeAreaInsetsDidChange:(UIEdgeInsets)insets |
| 197 | +{ |
| 198 | + // The home indicator's inset only applies beneath a tab bar along the bottom edge, which already |
| 199 | + // clears it. With the tab bar at the side, content runs to the bottom edge. |
| 200 | + CGRect tabBarFrame = _tabBarController.tabBar.frame; |
| 201 | + CGRect bounds = _tabBarController.view.bounds; |
| 202 | + if (CGRectGetWidth(tabBarFrame) < CGRectGetWidth(bounds) || CGRectGetMaxY(tabBarFrame) < CGRectGetMaxY(bounds)) { |
| 203 | + insets.bottom = 0; |
| 204 | + } |
| 205 | + // With no status bar above it, UINavigationBar still sits 24pt below the top edge, clear of the |
| 206 | + // display's corners. Content leaves the same gap, since the device reports no top inset there. |
| 207 | + if (insets.top == 0) { |
| 208 | + insets.top = 24; |
| 209 | + } |
| 210 | + if (UIEdgeInsetsEqualToEdgeInsets(insets, _contentInsets) || _eventEmitter == nullptr) { |
| 211 | + return; |
| 212 | + } |
| 213 | + _contentInsets = insets; |
| 214 | + static_cast<const RNTesterTabsIOSEventEmitter &>(*_eventEmitter) |
| 215 | + .onContentInsetsChange({ |
| 216 | + .top = insets.top, |
| 217 | + .left = insets.left, |
| 218 | + .bottom = insets.bottom, |
| 219 | + .right = insets.right, |
| 220 | + }); |
| 221 | +} |
| 222 | + |
| 223 | +@end |
| 224 | + |
| 225 | +Class<RCTComponentViewProtocol> RNTesterTabsIOSCls(void) |
| 226 | +{ |
| 227 | + return RNTesterTabsIOSComponentView.class; |
| 228 | +} |
0 commit comments