Resend.Client.pas

unit Resend.Client;

interface

uses
  System.SysUtils,
  System.Classes,
  System.Net.HttpClient,
  System.Net.URLClient,
  System.JSON;

type
  EResendError = class( Exception );

  TAttachmentFile = record
    FileName: string;
    Base64Content: string;
  end;

  TResendClient = class
  private
    FApiKey: string;
    FHttp: THTTPClient;
    FJSon: TJSONObject;
    FTo: Boolean;
    FUrl: string;
  public
    constructor Create( const AUrl, AApiKey: string );
    destructor Destroy; override;

    function SendEMail: string;
    function From( AFrom: string ): TResendClient;
    function Dest( ATo: TArray<string> ): TResendClient;
    function Subject( aSubject: string ): TResendClient;
    function Body( AHtmlBody: string ): TResendClient;
    function TextBody( ATextBody: string ): TResendClient;
    function Attachment( APaths: TArray<string> ): TResendClient;
    function SendEmail1( const AFrom: string; const ATo: TArray<string>;
      const ASubject, AHtml: string; const AText: string = '' ): string;
  end;

implementation

uses
  System.NetEncoding,
  System.IOUtils,
  System.NetConsts;

{ TResendClient }

function TResendClient.Attachment( APaths: TArray<string> ): TResendClient;
var
  LBytes: TBytes;
begin
  for var i := 0 to High( APaths ) do
  begin
    if not ( FileExists( APaths[ i ] ) ) then
    begin
      raise Exception.Create( 'Fichier non trouvé : ' + APaths[ i ] );
    end;
  end;

  var LAttachments := TJSONArray.Create;

  for var i := 0 to High( APaths ) do
  begin
    var LFileStream := TFileStream.Create( APaths[ i ], fmOpenRead or fmShareDenyWrite );
    try
      SetLength( LBytes, LFileStream.Size );
      LFileStream.ReadBuffer( LBytes, Length( LBytes ) );
    finally
      LFileStream.Free;
    end;

    var LBase64Content := TNetEncoding.Base64.EncodeBytesToString( LBytes );

    var LAttachment := TJSONObject.Create;
    LAttachment.AddPair( 'content', LBase64Content );
    LAttachment.AddPair( 'filename', TPath.GetFileName( APaths[ i ] ) );

    LAttachments.Add( LAttachment );
  end;

  FJSon.AddPair( 'attachments', LAttachments );

  Result := Self;
end;

function TResendClient.Body( AHtmlBody: string ): TResendClient;
begin
  FJson.AddPair( 'html', AHtmlBody );

  Result := Self;
end;

constructor TResendClient.Create( const AUrl, AApiKey: string );
begin
  inherited Create;

  FApiKey := AApiKey;
  FHttp := THTTPClient.Create;
  FJSon := TJSONObject.Create;
  FTo := False;
  FUrl := AUrl;
end;

function TResendClient.Dest( ATo: TArray<string> ): TResendClient;
begin
  if Length( ATo ) > 0 then
    FTo := True;

  var LToArray := TJSONArray.Create;
  for var LRecipient in ATo do
    LToArray.Add( LRecipient );
  FJson.AddPair( 'to', LToArray );

  Result := Self;
end;

destructor TResendClient.Destroy;
begin
  FHttp.Free;
  FJSon.Free;

  inherited;
end;

function TResendClient.From( AFrom: string ): TResendClient;
begin
  FJson.AddPair( 'from', AFrom );

  Result := Self;
end;

function TResendClient.SendEMail: string;
begin
  if not ( FTo ) then
    raise EResendError.Create( 'Au moins un destinataire est requis.' );

  var LContent := TStringStream.Create( FJson.ToJSON, TEncoding.UTF8 );
  try
    FHttp.CustomHeaders[ 'Authorization' ] := 'Bearer ' + FApiKey;
    FHttp.ContentType := 'application/json';

    var LResponse := FHttp.Post( FUrl, LContent );

    if ( LResponse.StatusCode < 200 ) or ( LResponse.StatusCode >= 300 ) then
      raise EResendError.CreateFmt(
        'Échec de l''envoi (HTTP %d) : %s',
        [ LResponse.StatusCode, LResponse.ContentAsString( TEncoding.UTF8 ) ] );

    var LResponseJson := TJSONObject.ParseJSONValue(
      LResponse.ContentAsString( TEncoding.UTF8 ) ) as TJSONObject;
    try
      if Assigned( LResponseJson ) and LResponseJson.TryGetValue<string>( 'id', Result ) then
        // Result contient l'ID du mail envoyé
      else
        raise EResendError.Create( 'Réponse inattendue de l''API Resend.' );
    finally
      LResponseJson.Free;
    end;
  finally
    LContent.Free;
  end;
end;

function TResendClient.SendEmail1( const AFrom: string;
  const ATo: TArray<string>; const ASubject, AHtml: string;
  const AText: string ): string;
var
  LJson: TJSONObject;
  LToArray: TJSONArray;
  LRecipient: string;
  LContent: TStringStream;
  LResponse: IHTTPResponse;
  LResponseJson: TJSONObject;
begin
  if Length( ATo ) = 0 then
    raise EResendError.Create( 'Au moins un destinataire est requis.' );

  LJson := TJSONObject.Create;
  try
    LJson.AddPair( 'from', AFrom );

    LToArray := TJSONArray.Create;
    for LRecipient in ATo do
      LToArray.Add( LRecipient );
    LJson.AddPair( 'to', LToArray );

    LJson.AddPair( 'subject', ASubject );
    LJson.AddPair( 'html', AHtml );

    if not AText.IsEmpty then
      LJson.AddPair( 'text', AText );

    LContent := TStringStream.Create( LJson.ToJSON, TEncoding.UTF8 );
    try
      FHttp.CustomHeaders[ 'Authorization' ] := 'Bearer ' + FApiKey;
      FHttp.ContentType := 'application/json';

      LResponse := FHttp.Post( 'https://api.resend.com/emails', LContent );

      if ( LResponse.StatusCode < 200 ) or ( LResponse.StatusCode >= 300 ) then
        raise EResendError.CreateFmt(
          'Échec de l''envoi (HTTP %d) : %s',
          [ LResponse.StatusCode, LResponse.ContentAsString( TEncoding.UTF8 ) ] );

      LResponseJson := TJSONObject.ParseJSONValue(
        LResponse.ContentAsString( TEncoding.UTF8 ) ) as TJSONObject;
      try
        if Assigned( LResponseJson ) and LResponseJson.TryGetValue<string>( 'id', Result ) then
          // Result contient l'ID du mail envoyé
        else
          raise EResendError.Create( 'Réponse inattendue de l''API Resend.' );
      finally
        LResponseJson.Free;
      end;
    finally
      LContent.Free;
    end;
  finally
    LJson.Free;
  end;
end;

function TResendClient.Subject( aSubject: string ): TResendClient;
begin
  FJson.AddPair( 'subject', ASubject );

  Result := Self;
end;

function TResendClient.TextBody( ATextBody: string ): TResendClient;
begin
  FJson.AddPair( 'text', ATextBody );

  Result := Self;
end;

end.